melGeek

Talk to Maya

2006-08-16T21:57:00.000-07:00

WOW! This looks like it could be really interesting. I hope to try it tomorrow. It's a plug-in that allows you to issue commands to Maya via your microphone and voice recognition.

Batching in MEL

2006-06-06T16:28:00.000-07:00

People speak of "batching" in Maya. All this means is let the computer do the repetitive work for you. For a specific example, lets say that half way through the animation phase, your art director decides the main character of your game really needs to have a green hat to "communicate the angst of the characters plight to the player better".

For each animation already complete, you'll need to import a hat model and then constrain it to the characters head. This is the boring monotonous part of production. Help MEL help you. Maya doesn't have a built in Batch function, but it is easy enough to quickly code something up.

This example will demonstate the code I like to use for simple batching. You can utilize these concepts to automate which ever tasks it is you'll need to perform to a list of files.


string $fullPathAndName = `fileDialog`;
string $sourcePath = dirname($fullPathAndName);
string $sourcePath = ($sourcePath + "/");
string $myFiles[] = `getFileList -fld $sourcePath -filespec "*.mb"`;
for ($eachFile in $myFiles)
{
//your tasks go here
}
print ("Done doing stuff for all the files in this directory " + "\"" + $sourcePath + "\"" + "!" + "\n");

Let's break that down into bit sized chucks of understanding ...


string $fullPathAndName = `fileDialog`;

The fileDialog command launches an 'Open' window. By selecting any file in that directory, the script will now know the network path AND filename of whatever file is chosen. Store that in the $fullPathAndName variable.

Next you need to get just the path to the file so you and MEL know what directory to work on. Luckily Maya has a built in dirname command. You provide the command a full path and filename string and it will automatically return just the directory path. Store that in the $sourcePath variable.

The one drawback to the dirname command is it doesn't include the trailing "/" at the end so you'll have to reassign the $sourcePath variable to include its current contents plus the trailing "/". This line string $sourcePath = ($sourcePath + "/"); does exactly that.

Now you know the directory to process. Next you'll tell Maya to look at all the files in that directory and store them in a list. string $myFiles[] = `getFileList -fld $sourcePath -filespec "*.mb"`; is the key here. The command getFileList does what it says, you're telling MEL where to get the files from by the -fld $sourcePath bit. I am sure you can guess that the -fld is short for folder. Use a string array called $myFiles[] or something similar to store the files.

At this point its just simple for loops and other custom code to do what you like to each file. In our example, you'd import the hat, return the character to the bind pose, constrain the hat to the head, and "be kind and rewind" the animation. Lastly, you can print out a report of what happened. If you use error checking properly, you can even note what files failed for whatever reason. More on error checking later as it deserves a post all it's own.

PS- I (Chad) have moved my blog over to here.

Sorry Bryan

2005-09-14T10:47:00.000-07:00

Cheers,
Chad

Master Class Notes

2005-09-07T20:47:00.000-07:00

If you were at the Motion Builder Master Class I (Chad) co-presented this year at siggraph and are missing the final notes, let me know by commenting and I'll see what I can do to get them to you.

Cheers,
Chad

Workflow improvements: Connection Editor

2005-09-01T12:01:00.000-07:00

I work with the connection editor almost continuously throughout the day and I got to thinking that it would save me a lot of time if the connection editor would just open up based on a selection with things already loaded. So here we go:

I decided that I would like it to load the first selection to the left side of the connection editor, as I always have it set to from -> to. Then anything else selected would open on the right side.

// SCRIPT: ijConnectionEditor
// AUTHOR: Ian Jones - mel@shrtcww.com
// DATE: September 1, 2005
// Version: 1.0
//
// DESCRIPTION: Opens the connection editor and loads left/right side based on
//                 a selection
//
// ASSUMPTIONS: Connection Editor is set to: from -> to
//
global proc ijConnectionEditor()
{
    // Save the current selection/size
    string $selection[] = `ls -sl`;
    int $numSelections = `size($selection)`;

    ConnectionEditor;
   
    // If selection[0] exists: load to the left side of the CE
    if ( $numSelections > 0 )nodeOutliner -e -replace ( $selection[0] ) connectWindow|tl|cwForm|connectWindowPane|leftSideCW;
   
    // If selection[1] exists: load to the right side of the CE
    if ( $numSelections > 1 ) nodeOutliner -e -replace ( $selection[1] ) connectWindow|tl|cwForm|connectWindowPane|rightSideCW;

   
    // If more than 2 objects selected 
    // add additional to the right side.
    if ( $numSelections > 1 )
    for( $n=2; $n<($numSelections ); $n++ )
    {
        nodeOutliner -e -addObject $selection[( $n )] connectWindow|tl|cwForm|connectWindowPane|rightSideCW;
    }
}

Already saving me a bunch of time. Hope you enjoy.

Batches? We DO need stinking batches

2005-08-29T22:01:00.000-07:00

First off, thanks to Josh and Ian for the posts. We're running the gamut from workflow enhacements to full on UI creation. Booya.

I am tinkering with my next post, which I hope to have up by this weekend. I want to talk a bit about creating a batch script.

Do you have a lot of files that you need to alter in the same way? Do you wish that there was a way to automatically process all these files at once? Well batching is for you!

More soon.

Cheers,
Chad

QuickDragSelect

2005-08-22T21:44:00.000-07:00

Just a quickie... literally.

Here's something i have in my custom modeling marking menu that toggles on the quickdragselect option in the preferences. I don't *think* there's another way to turn it on and off quickly without going into the prefs, so this proves to be super handy when i'm manipulating verts. It's even better when you envoke the soft mod tool.

if (`selectPref -q -cld`)
selectPref -cld 0;
else
selectPref -cld 1;

For those that don't know what clickdragselect is, it basically lets you click and drag (with move, rotate, or scale), as opposed to clicking, letting go, then middle mouse dragging the selection.

Hmm.. can that code be even more simplified?

Quick and dirty light editor

2005-07-29T11:41:00.000-07:00

Eventually we all run across a shot that requires us to have a lot of lights that we want to be able to edit quickly. For myself, it was a downtown street with a slew of street lights. It quickly became tedious to tweak the lights with the attribute editor. This was especially true when I wanted to tinker with the decay rates. You would select a light, open the decay rate pull down, make a selection and repeat over and over – just to find you preferred it better before.

So I quickly wrote some code to create my own simplified attribute spreadsheet:

string $window = `window -title "LightEditor " -widthHeight 600 300`;
paneLayout;  

select -r `listTransforms -lights`;    
string $activeList = `selectionConnection -activeList`;

spreadSheetEditor -mainListConnection $activeList -ln true -showShapes true ;

showWindow $window;

This gives us a quick spread sheet with access to the defaults: color, intensity, ray trace/depth map shadows, shadow color etc. Great – but my inspiration was to deal with the decay rate and by default it's not listed. This is because only keyable attributes show up in the spreadsheet editor so you miss out on valuable things like dmap resolution/filter, decay rates which, by default, are not keyable.

To fix this we'll make a small proc to make additional values we want keyable visible. Decay rate is unique in that even if made keyable it doesn’t appear so, we'll make a stand in and connect the two.

proc showLightAttributes() { string $selection[] = `listTransforms -lights`; for($obj in $selection) { string $shapes[] = `listRelatives -shapes $obj`; if ( !`objExists ( $shapes[0] +".Decay" )` ) { addAttr -k true -dv 0 -min 0 -max 3 -at double -ln Decay $shapes[0]; connectAttr ( $obj + ".Decay") ( $obj + ".decayRate"); } setAttr -k true ( $obj + ".dmapFilterSize"); setAttr -k true ( $obj + ".dmapResolution"); } }
Now we'll make it easier to execute that code when we need to by making a menu on the light editor. While were at it will add the ablity to reselect all the lights.

The final code:

// SCRIPT: ijLightEditor.mel // AUTHOR: Ian Jones - mel@shrtcww.com // DATE: July 29, 2005 // Version: 1.0 // // DESCRIPTION: Creates a simply mass light editor // // global proc ijLightEditor() { string $window = `window -title "LightEditor by Ian Jones" -menuBar true -menuBarVisible true -widthHeight 600 300`; menu -label "Tools" -tearOff false; menuItem -label "Re-select Lights" -command ("select -r `listTransforms -lights`"); menuItem -label "Show Light Attributes" -command ("showLightAttributes"); paneLayout; select -r `listTransforms -lights`; string $activeList = `selectionConnection -activeList`; spreadSheetEditor -mainListConnection $activeList -ln true -showShapes true ; showWindow $window; } global proc showLightAttributes() { string $selection[] = `listTransforms -lights`; for($obj in $selection) { string $shapes[] = `listRelatives -shapes $obj`; if ( !`objExists ( $shapes[0] +".Decay" )` ) { addAttr -k true -dv 0 -min 0 -max 3 -at double -ln Decay $shapes[0]; connectAttr ( $obj + ".Decay") ( $obj + ".decayRate"); } setAttr -k true ( $obj + ".dmapFilterSize"); setAttr -k true ( $obj + ".dmapResolution"); } }

Zero fun!

2005-07-26T15:24:00.000-07:00

melGeek
Howdy everyone out there in mel land! Just testing this out for my first blog, but here's a little workflow tip that makes life that much easier.

So, everyone knows the w, e, r shortcuts for your transform tools, right?

shift + w/e/r sets keys on trans/rot/scale specifically
left mouse click + w/e/r gives you a nice marking menu

Following that theme, I've made ctrl + w/e a hotkey for zeroing out selected objects' translates/rotates using the following code:

string $sel[] = `ls -sl`;

for ($obj in $sel){
string $objAttr[] = `listAttr -k -u -st "translate*" $obj`;
for ($attr in $objAttr){
setAttr ($obj + "." + $attr) 0;
}
}

The nice thing about this, is that if one of your selected objects has a locked attribute, the zero out script will not halt. Definitely useful when animating, and even more useful during the setup process. Just think of all the facial controls (a la osipa) that you need to handle when facial animating... ahh.

To make the script zero out rotates, replace translate with rotate (same for scale, but change 0 to 1 as well).

I'm such a workflow nut.

melGeek(s)

2005-07-25T21:53:00.000-07:00

We have 2 new contributors to help keep melGeek up and running. Please welcome Josh Carey of the Animation Farm, and Ian Jones. I am looking forward to more posts and general mel goodness.

huzzah!

Call for contributers

2005-07-21T08:06:00.000-07:00

Is anyone interested in contributing to the site? Let me know by commenting on this post and I'll hook you up with the info. Time is not on my side of late, and I want to keep this Blog alive.

Playblasting alternative

2005-05-09T20:50:00.000-07:00

Hey there blogophiles.

The topic of using the fbx for quicktime plugin for previewing animations instead of playblasting was discussed over at CGCHAR a bit.

Now first off, let me tell you what the fbx for quicktime is and point you towards the two plugins you'll need. Then, and only then will I hook ya'll up with a script that takes care of some of the messy export bits.

FBX is the Motion Builder file format. Alias and Kaydara before them are touting the .fbx as the 3D interchange file format. it takes models textures (maybe lights too ?) from one 3D app to another. So there is a plugin to generate a .fbx from/to Maya. This basically lets you model, joint and bind your puppet and then export for motion builder for mocap and/or character animation.

Anyhow a while back the good folks who make Motion Builder put out a FBX for Quicktime plugin. You load your .fbx file in QT and playback in real time. But wait there is more ... You can pan, zoom and orbit your animation - right there in QT. This is a great thing for games as you can't be playing your action to a stationary camera for in game stuff.

So here is the link to get the plugins. You'll need to register, but its free. FBX plugins.

So now for the bad news, the fbx for QT plugin only allows the playback of animation on joints. It doesnt support contraints. So for you character animator's out there, you'll need to bake the animation from your control rigs to joints. You can use the bake simulation command to do so.

Using the everpopular and pretty cool rig LowMan
as a test bed, I wrote a little script that does the following.

Saves your file (Maya .mb)
Bakes all joints
exports a .fbx to a subfolder in the currenlty loaded scene's location
reopens your saved Maya .mb

I added the save and reopen the .mb steps so you wouldn't have to pick all the joints and delete the channels that the bake command creates. Plus its good to save a lot.

Here's the code, let me know what you think. I'd like to test it out on other characters, and see if I can get blendshaps in too. But, Alas, time is not on my side. Do let me know if you come accross something, I may try and squeeze some time into this if the demand is out there.


//cmPlayblastFBX.mel
//------------------------------------------//
//------------------------------------------//
// SCRIPT: cmPlayblastFBX.mel
// AUTHOR: Chad Moore - smap2d@gmail.com
// DATE: May 09, 2005
// Version: 1.0
//
// DESCRIPTION: Preps a .mb file for viewing in FBX/Quicktime
//   
//
// USAGE:  1. When you are ready to preview in 
//quicktime using .fbx, run the script.
//   
//
// NOTES:  1. The script will fore a save operation on your .mb file, export the .fbx and then reopen you .mb file, 
//        so you do not have to worry about the keyframes on the joints the bake command creates.
//      2. The script will write the .fbx to a folder called "exportedFBX" under the directory of the current scene
//       
//
// LIMITATIONS: 1. You must have the fbx plug-in for proper export out of Maya 
//   
//      
//-----------------------------------------//
//-----------------------------------------//

global proc cmPlayblastFBX()

{
string $sourceFile = `file -q -sn`;
string $sourcePath = dirname($sourceFile);
string $sourcePath = ($sourcePath + "/");
string $fbxFolder = "exportedFBX/";
string $FBXfile = basename($sourceFile, ".mb");
string $destPath = ($sourcePath + $fbxFolder);

sysFile -makeDir $destPath;

file -s -f;

string $allJoints[] = `ls -type joint`;
int $startTime = `playbackOptions -q -ast`;
int $endTime = `playbackOptions -q -aet`;

bakeResults 
-simulation true 
-t ($startTime + ":" + $endTime)
-sampleBy 1 
-disableImplicitControl true 
-preserveOutsideKeys true 
-sparseAnimCurveBake false 
-controlPoints false 
-shape true 
$allJoints
;

FBXExportShowUI -v 0;
FBXExport -f ($destPath + $FBXfile) -caller "FBXMayaTranslator"; 

file -f -o $sourceFile;

print ("Done exporting the " + $FBXfile + ".fbx file." + "\n");
}

cmPlayblastFBX;

Oh yeah, I'll go over some of the commands above soon. They're really great and can be used for an auto save or batch processing script.

George's Pizza Shop

2005-04-06T21:55:00.000-07:00

Our buddy George gave me an idea for demoing the next two topics I wanted to bring up. For loops and the Random Function. First run this...


{
curve -name pizzaCurve -d 3 -p 0 0.0310559 0 -p -4.875776 0.0621118 0 -p -10.093168 0.0621118 0 -p -14.813665 0 0 -p -19.906832 0.0621118 0 -p -20.900621 1.987578 0 -p -19.968944 4.875776 0 -p -18.074534 3.136646 0 -p -17.919255 2.018634 0 -p -14.875776 2.049689 0 -p -10 2 0 -p -5 2 0 -p 0 2 0 -k 0 -k 0 -k 0 -k 1 -k 2 -k 3 -k 4 -k 5 -k 6 -k 7 -k 8 -k 9 -k 10 -k 10 -k 10 ;
revolve -n pizzaGEO -ch 1 -po 0 -rn 0 -ssw 0 -esw 360 -ut 0 -tol 0.01 -degree 3 -s 8 -ulp 1 -ax 0 1 0 "pizzaCurve";
DeleteHistory pizzGEO;
delete pizzaCurve;

polyCylinder -name pepperoni_geo -r 1 -h 0.25 -sx 8 -sy 1 -sz 1 -ax 0 1 0 -tx 1 -ch 1;
setAttr pepperoni_geo.ty 2.25;

duplicate -rr; 
for ($i=1; $i<50; ++$i) 
duplicate -rr -st; 
;
}

There isnt anything special about the above code, I just drew a curve and revolved it, made a cylander and duplicated it 49 times. I did this with echo all commands on and used the important bits from the script editor.

First lets get random.

There is a way to setAttr for an object randomly. Its called the rand command, here is an example. Make a poly cube and then run this...


{
int $random = `rand -10 10`;
setAttr "pCube1.translateX" $random;
}

The rand -10 10 allows you to set the attribute to any value between those two. Pretty sneaky sis.

Anyway lets get to the for loop. Now if you look at the above code theres a nasty little bit of for loopery happening here for ($i=1; $i<50; ++$i) .

We address what that means later. There is a much easier way to do a for loop. Maya has a for in loop. We are going to use that to move about all 50 peperonis randomly. Heres how it goes.


{
select -r "pepperoni_*";
string $peps[] = `ls -sl -exactType transform`;

for ($each in $peps)
      {
           float $randomX = `rand -15 15`;
           float $randomZ = `rand -15 15`;
           
           setAttr ($each + ".tx") $randomX;
           setAttr ($each + ".tz") $randomZ;
      }
}

So the for in loop is pretty sassy, its saying in english "For each one of you in ths array... do something". You can declare the $each variable, although you do not need to.

see what condition your condition is in...

2005-03-22T21:04:00.000-08:00

Let's talk conditions. Specifically the if then conditional statement.

Lets say you have a joint chain - 5 nodes, named leg, knee, ankle, foot, toe. You want to automaticaly prefix either "rt" or "lf" depending on where the joint is in space. Naming coventions are vital, and it so happens that the right side of your puppet should be on the negative X axis.

So lets say this in english, then in mel...

If the legs translate X is less than zero, name it right, if not name it left. Sounds sassy right. OK mel me on up...


{
string $leg = "leg";
string $right = "rt";
string $left = "lf";
float $legPos[] = `xform -ws -q -rp $leg`;
if ($legPos[0] <= 0);
{
rename $leg ($right + "_" + $leg);
}
}

Super cool huh? Here is how to use the else part.


{
string $leg = "leg";
string $right = "rt";
string $left = "lf";
float $legPos[] = `xform -ws -q -rp $leg`;

if ($legPos[0] <= 0)
     {
     rename $leg ($right + "_" + $leg);
     }
else
     {
     rename $leg ($left + "_" + $leg);
     }
}

Sweet sassy molassy thats cool! Can you figure out how to prefix all the joints with a similar set up?

string $slacker;

2005-03-17T20:21:00.000-08:00

So if your a fan of reading blogs, you have of course, seen the "Sorry I havent posted in a while" type post. Here is my MEL version.


{
int $lastPost = 7;
int $today = 17;
string $sentance = "Sorry I haven't posted in ";
string $days = " days";

print (($sentance + ($today - $lastPost) + $days));
}

Inspired 3D Advanced Rigging and Deformations

2005-03-07T10:15:00.000-08:00

Here's a link to a new book due out Around April 8th. Brad and John and I used to work together way back in the day. Although they are both "nuttier than a bag of weasels", the book should rock.

;)

lets get practical, practical, I wanna get practical

2005-02-28T21:24:00.000-08:00

OK so lets use some commands and tricks that you'll actually need in the throws of production. Getting and setting attributes is key to finding out information, and setting values.

First make a cube and name it "cube". Move it about randomly with the move tools.
Run this...


{
float $myPos = `getAttr cube.ty`;
print $myPos;
}

the command getAttr retrieves the value for the attribute you specify. You can store this value in a variable and do cool things with it. Now try this.


{
float $myPos = `getAttr cube.ty`;
setAttr cube.ty ($myPos + 5);
}

So there you have it, getting and setting values is the bees knees. One of the great tricks of the Maya masters is getting the world space values for an object. This is handy because if you getAttr for an object nested in a hierarchy, you'll get the attr in local coordinate space (refrencing the parent).

So here's the trick, you have to use the xform command and specify the world space flag. Something like this...


{
float $myPos[] = `xform -worldSpace -query -translation cube`;
print $myPos;
}

That should return three floats translate X, Y and Z. One last thing to keep in mind, if your trying that on an object that has frozen transformations (and please do freeze transforms whenever you can, everyone likes a nice clean scene. Ahhhh refreshing).

I digress. If you query the world space of an object with frozen xforms, you'll get 0's for the return values, since the transfroms are set to 0. You need to specify the rotate pivot, this flag tells you the world space coridinates for the pivot point, assuring the exact placement in 3D space. Like this...


{
float $myPos[] = `xform -ws -q -rp cube`;
print $myPos;
}

Weird, I know. But that's the way the cookie crumbles sometimes. I gotta give a shout out to -: m a c a r o n i K a z o o :- for the help with the roation pivot trick over at the Production Log for the Computer Graphics Animated Short Film: Jonh and His Dog -> stupid newbie world space query

Booya.

comments, arrays and tokenize

2005-02-10T21:41:00.000-08:00

I forgot to mention comments. You can easily provide feedback and notes to the users of your scripts (including yourself) by adding comments. Like this...


//this is a comment
int $firstNum = 1;
int $secondNum = 2;
//lets add the two variables
print ($firstNum + $secondNum + "\n");

OK thats pretty easy, sorry I didn't mention it earilier.

A quick note on arrays. An array is a varible that contains more than one peice of information. Like this...


int $myNumbers[] = {5, 7, 9};

Of course you can affect all or just parts of the array. You'll need to specify which part...


{
int $myNumbers[] = {5, 7, 9};
print ("The first number in the array is " + $myNumbers[0] + "\n");
print ("The second number in the array is " + $myNumbers[1] + "\n");
print ("The third number in the array is " + $myNumbers[2] + "\n");
}

Keep in mind the first item is labeled 0, not 1. I hope that makes sense for you. Now on to "tokenize".

Tokenize is a function that takes a string and breaks it into an array via a character you specify. Lets say you have this...


string $myString = "lf_Arm_JNT";

As in "Left arm joint". You simply want to rename it to rt_Arm_JNT. Here is how tokenize can help.


{
string $myString = "lf_Arm_JNT";
string $right = "rt";
string $newString;

//we'll need another string to store the parts of the first, hang in there I'll show ya
string $myToks[];

tokenize($myString, "_", $myToks);
string $newString =  ($right + "_" + $myToks[1] + "_" + $myToks[2] + "\n");
print ($newString + "\n");
}

So tokenize reads like this in english...

tokenize(this string, by this character, and store all the parts in this other string)

pretty cool beavis.

Scope

2005-02-05T21:29:00.000-08:00

Variables have Scope. This determines where the variable can hold data. If you don't manage scope (dont worry there is an easy way to do so) the variables you declare will live as long as Maya is open. This may mean that you'll have to quit Maya to regain your variables.

Anyhow, here is what you do...


{
int $myInt = 5;
}

The "Curly Braces" constrain variable $myInt to just that space. As we progress you'll see the importance of this workflow.

What is the real name of the Curly Braces? Is calling them Curly braces acceptable?

variables

2005-02-03T20:23:00.000-08:00

Lets begin with some info on variables. Varibles come in 3 main types (to start with). they are int, float and string. Int's are whole numbers (4, 238, 90) where floats are decimals (8.33, 9382.22, 5.5). Strings are text (chad, mel rules).

Variables are placeholders, they store certain types of information as described above. You must first declare the variable, something that looks like this...


int $myNum;

This means that Maya now knows that there is a variable called $myNum. It has no value as of yet. You'll need to set it equal to something. Like this...


int $myNum = 5;

Now Maya nows that $myNum is equal to 5. You can declare, and set a value at the same time by just using the format above.

Here are smaple variable declartions for the three types of variables mentioned above...


int $myNum = 37;

float $myNum = 4.3;

string $myString = "Chads string";

If you type any of these (or your own exaples) in the command line or script editor, Maya should return the result. Go ahead try it. I dare you... just kidding.

So thats great but what does it all mean? Well lets do some math (yeah! math!!). Put this in your script editor and smoke it.


int $firstNum = 2;
int $secondNum = 3;
int $mySum = ($firstNum + $secondNum);

A note on the parenthsis... When you are putting two peices of information together, MEL needs you to put them in parenthesis. You'll use this all the time, more about it as we go. We're getting ahead of ourselves.

Let's get "all crazy like" with a string and an int...


int $myNum = 5;
string $myString = "The number is ";
print ($myString + $myNum);

This should return "The number is 5". Just like when we were adding, we need the parenthesis for the print statement. You'll use prints to provide feedback to users, and also for testing when you are creating or debugging scripts.

Give this a whirl, and I'll post soon again... promise.

Links...

2005-02-02T20:48:00.000-08:00

Links are up. If you know any others let me know. Also the best resource you have available is the "MEL command reference" from the help section. By the way, if you need help on a command (xform for example) you can type from the script editor...


help xform;

This prints the help file in the top of the script editor, to launch a web browser use this flag


help -doc xform;

About the links...

Brian Ewert-
has over 100 MEL tips tricks and goodies.

nerfsafetysquid.com-
Dan Neufeldt has some great how to's and scripts for download.

Highend3d.com-
THE web resource for MEL scripts and Maya tutorials.

Creature TD-
Joe Harkins Character Rigging Forums.

Jason Schleifer-
Super MEL Ninja.

melscripting.com forums-
Forum by the authors of "MEL scripting for Maya Animators".

The books link to amazon is broken right now, check it later?

Script editor usage...

2005-02-02T20:18:00.000-08:00

OK,

Script Editor usage is covered in many books and tutorials now. So I urge you to google for some tutorials on it. Its my intention to post links on the right hand side to other MEL sites and forums, and I'll get to it soon. I promise.

Anyhow, here is what you can start looking into now...

1. Echo all commands.
2. MMB drag text out of script editor to shelf for button creation.

Armed with those two tools you are on the path to total world domination!

An introduction

2005-02-01T20:51:00.000-08:00

So, I figure I can make this into a production log for my MEL self education. A bit about me... I have been using Maya for years, and consider myself to be fairly well versed with MEL. However I have set a goal for myself, that goal is to be a MEL guru.

So Thats me, and my goal. I'll be posting real soon with some basics to get other people started, and solidify them in my head. Then we will get all funky like.